home *** CD-ROM | disk | FTP | other *** search
/ Shareware Grab Bag / Shareware Grab Bag.iso / 090 / byteibm.arc / DAHMKE.ARC / MCDFIG7.ASM < prev    next >
Assembly Source File  |  1985-07-12  |  8KB  |  326 lines
  1.        PAGE 66,132
  2. ;
  3. ;       Utility subroutines for use with MS-FORTRAN
  4. ;
  5. ;    by Mark Dahmke
  6. ;    May, 1986
  7. ;
  8.         PUBLIC  SRCHF, SRCHN, CHDIR, GETDIR, GETDFS
  9. ;
  10.     SUBTTL    'MACROS'
  11.     PAGE
  12. ;
  13. ;------ MACROS ------
  14. ;
  15. DOS    MACRO    
  16.     INT      21H     ;REQUEST DOS SERVICE
  17.     ENDM
  18. ;
  19. ;---------------------------------------------------------------
  20. ;  SETFRAME:  Sets the environment upon entry to a subroutine.
  21. ;
  22. SETFRAME MACRO
  23.     PUSH    BP        ;SAVE FRAMEPOINTER ON STACK
  24.     MOV    BP,SP
  25.       ENDM
  26. ;
  27. ;  POPRET:    Restores the BP register and returns to the
  28. ;             calling FORTRAN routine after cleaning up the
  29. ;             stack.
  30. ;
  31. POPRET  MACRO   NPARMS        ;RETURN FROM SUBR.  NPARMS=NUMBER OF PARMS
  32.     POP    BP
  33.     RET    NPARMS*4
  34.     ENDM
  35. ;
  36. ; GETPARM: returns a pointer to a parameter in the call list.
  37. ; 
  38. ;       Operands:  X = the number of the desired parameter
  39. ;                MAX = the maximum number of parameters in
  40. ;                      the call list.
  41. ;
  42. ;       Result: The ES:BX register pair points to the parameter.
  43. ;
  44. GETPARM    MACRO     X,MAX         ;PARAMETER NUMBER (IE, 1,2,3)
  45.     LES    BX,DWORD PTR SS:[BP+(MAX-X)*4+6] 
  46.     ENDM
  47. ;
  48. ;
  49. ;--------------------------------------------------------------
  50. ;
  51.     SUBTTL    'DATA SEGMENT'
  52.     PAGE
  53. ;-------------------------------
  54. DATA    SEGMENT PUBLIC 'DATA'
  55. ;
  56. SDMA    DB      128 DUP(0)         ;DMA BUFFER FOR SRCHF AND SRCHN ROUTINES
  57. ;
  58. FCB     DB      0
  59.         DB      8 DUP(0)        ;FILE NAME (1-8)
  60.         DB      0,0,0           ;FILE TYPE (9-11)
  61.     DW    0        ;CURRENT BLOCK (12-13)
  62.     DW    0        ;LOGICAL RECORD SIZE (14-15)
  63.     DW    0,0        ;FILE SIZE (16-19)
  64.     DW    0        ;DATE (20-21)
  65.     DW    0,0,0,0,0     ;RESERVED (22-31)
  66.     DB    0        ;CURRENT RELATIVE RECORD
  67.     DW    0,0        ;RELATIVE RECORD NUMBER
  68.         DB      0
  69.     DB    0
  70. ;
  71. IDRIVE    DW    0
  72. STRING    DW    0
  73. STRING_SEG DW    0
  74. ;
  75. DATA    ENDS
  76. DGROUP    GROUP    DATA 
  77. ;
  78.     SUBTTL    'CODE SEGMENT'    
  79.     PAGE
  80. ;
  81. CODE    SEGMENT    'CODE'
  82.     ASSUME    CS:CODE, DS:DGROUP, SS:DGROUP
  83. ;
  84. ;-------------------------------
  85. ;SEARCH FOR FIRST DIRECTORY ENTRY
  86. ;
  87. ; PARM LIST:    CALL SRCHF(IDRV,FSPEC,RFNAME)
  88. ;
  89. ; INPUT: IDRV, FSPEC -- 0=CURRENT, 1=A, 2=B,   FSPEC= ????????.???
  90. ; OUTPUT: RFNAME -- FILENAME.TYP
  91. ;
  92. SRCHF   PROC    FAR             ;SEARCH FOR FIRST DIR ENTRY
  93.     SETFRAME
  94. ;
  95.     GETPARM    1,3        ;GET DRIVE CODE    ADDR
  96.     MOV    AX,ES:[BX]    ;GET VALUE
  97.     MOV    IDRIVE,AX
  98.     MOV    FCB,AL        ;SET UP FCB
  99. ;
  100.     GETPARM 2,3        ;GET FILESPEC
  101. ;
  102.     MOV    STRING,BX
  103.     MOV    STRING_SEG,ES    ;SAVE PTR AND SEG
  104. ;
  105.     MOV    DI,OFFSET DGROUP:FCB+1
  106.     PUSH    DS        ;SAVE DS
  107.     PUSH    DS
  108.         POP      ES        ;SET UP DEST  
  109.     MOV     SI,STRING
  110.     MOV    DS,STRING_SEG
  111.     MOV    CX,11
  112.     REP    MOVSB        ;COPY FILESPEC 11 CHARS
  113. ;
  114.     POP    DS        ;RESTORE DS
  115.     MOV    DX,OFFSET DGROUP:SDMA
  116.         MOV     AH,1AH
  117.         DOS            ;SET DMA ADDRESS
  118. ;
  119.         MOV     DX,OFFSET DGROUP:FCB    
  120.         MOV     AH,11H          ;SEARCH-FIRST BDOS COMMAND
  121.         DOS
  122. ;
  123.         CMP     AL,0FFH    
  124.         JZ      NO_FILES        ;IF NO FILES, SKIP OUT.
  125. ;
  126.     GETPARM    3,3        ;GET RETURN FILENAME ADDR IN ES:BX
  127.     MOV    DI,BX        ;SET UP ES:DI POINTER FOR MOVE
  128.     MOV    SI,OFFSET DGROUP:SDMA+1    ;POINT TO FILE NAME
  129.     PUSH    DS
  130.     POP    ES        ;SET UP DEST SEG
  131.     MOV    CX,11        ;MOVE 11 BYTES
  132.     REP    MOVSB
  133. ;
  134.         JMP    S_DONE
  135. ;
  136. ;
  137. NO_FILES:                       ;IF NO FILES ARE PRESENT, 
  138.     GETPARM    3,3
  139.     MOV    BYTE PTR ES:[BX],'?'    ;PUT A ? IN FIRST CHAR 
  140.                     ;OF OUTPUT FILE NAME
  141. S_DONE: POPRET    3
  142. SRCHF     ENDP
  143. ;    
  144. ;-------------------------------
  145. ;SEARCH FOR NEXT DIRECTORY ENTRY
  146. ;
  147. ; PARM LIST:    CALL SRCHN(IDRV,FSPEC,RFNAME)
  148. ;
  149. ; INPUT: IDRV, FSPEC -- 0=CURRENT, 1=A, 2=B,   FSPEC= ????????.???
  150. ; OUTPUT: RFNAME -- FILENAME.TYP
  151. ;
  152. SRCHN   PROC    FAR             ;SEARCH FOR NEXT  DIR ENTRY
  153.     SETFRAME
  154. ;
  155.     GETPARM    1,3        ;GET DRIVE CODE    ADDR
  156.     MOV    AX,ES:[BX]    ;GET VALUE
  157.     MOV    IDRIVE,AX
  158.     MOV    FCB,AL        ;SET UP FCB
  159. ;
  160.     GETPARM 2,3        ;GET FILESPEC
  161. ;
  162.     MOV    STRING,BX
  163.     MOV    STRING_SEG,ES    ;SAVE PTR AND SEG
  164. ;
  165.     PUSH    DS        ;SAVE SEG
  166.     PUSH    DS
  167.     POP    ES
  168.     MOV    DI,OFFSET DGROUP:FCB+1
  169.     MOV    SI,STRING
  170.     MOV    DS,STRING_SEG
  171.     MOV    CX,11
  172.     REP    MOVSB        ;COPY FILESPEC 11 CHARS
  173. ;
  174.     POP    DS
  175.     MOV    DX,OFFSET DGROUP:SDMA
  176.         MOV     AH,1AH
  177.         DOS            ;SET DMA ADDRESS
  178. ;
  179.         MOV     DX,OFFSET DGROUP:FCB
  180.         MOV     AH,12H          ;SEARCH-NEXT  BDOS COMMAND
  181.         DOS
  182. ;
  183.         CMP     AL,0FFH    
  184.         JZ      NNO_FILES        ;IF NO FILES, SKIP OUT.
  185. ;
  186.     GETPARM    3,3            ;GET RETURN FILENAME ADDR IN ES:BX
  187.     MOV    DI,BX            ;SET UP ES:DI POINTER FOR MOVE
  188.     MOV    SI,OFFSET DGROUP:SDMA+1    ;POINT TO FILE NAME
  189.     MOV    CX,11            ;MOVE 11 BYTES
  190.     REP    MOVSB
  191. ;
  192.      JMP    N_DONE
  193. ;
  194. NNO_FILES:                       ;IF NO FILES ARE PRESENT, 
  195.     GETPARM    3,3
  196.     MOV    BYTE PTR ES:[BX],'?'    ;PUT A ? IN FIRST CHAR OF OUTPUT FILE NAME
  197.                                 ;OUTPUT FILE NAME
  198. N_DONE: POPRET    3
  199. SRCHN    ENDP
  200. ;----------------------------------
  201. ;  GETDIR:  RETURN ASCII STRING CONTAINING CURRENT DIRECTORY PATH
  202. ;
  203. ;            
  204. ;  CALL GETDIR(PATH,IDRIVE,ICODE)    
  205. ;
  206. ;       PATH  = CHARACTER*64          (RETURNED PATH NAME)
  207. ;       ICODE = INTEGER               (RETURN CODE)
  208. ;       IDRIVE= INTEGER               (DRIVE, 0=DEFAULT, 1=A, 2=B)
  209. ;
  210. ;    NOTE: PATH IS RETURNED WITH NO STARTING BACKSLASH
  211. ;          AND WITHOUT THE DRIVE LETTER AND COLON.
  212. ;          THE PATH STRING IS TERMINATED WITH A ZERO BYTE.
  213. ;
  214. GETDIR  PROC    FAR             ;GET PATH NAME ON IDRIVE
  215. ;
  216.     SETFRAME
  217. ;
  218.     GETPARM    1,3
  219.     MOV    STRING,BX    ;SAVE PTR TO OUTPUT STRING AREA
  220.     MOV    STRING_SEG,ES    ;AND SEG
  221. ;
  222.     GETPARM    2,3        ;GET DRIVE CODE    ADDR
  223.     MOV    AX,ES:[BX]    ;GET VALUE
  224.     MOV    IDRIVE,AX    ;AND SAVE IT
  225. ;        
  226.     PUSH    DS
  227.     MOV    SI,STRING    ;SET UP PATH STRING POINTER
  228. ;
  229.     MOV    DX,IDRIVE    ;GET DRIVE NUMBER
  230.     MOV     AX,STRING_SEG
  231.     MOV    DS,AX
  232. ;
  233.     MOV    AH,47H        ;GET DIRECTORY NAME
  234.         DOS
  235. ;
  236.     GETPARM    3,3
  237.     MOV    AH,0        ;CLEAR OUT AH
  238.     MOV    ES:[BX],AX    ;STORE IT
  239. ;    
  240.     POP    DS
  241.         POPRET    3
  242. GETDIR    ENDP
  243. ;----------------------------------
  244. ;  CHDIR:  SET DIRECTORY PATH TO STRING FOUND IN PATH.
  245. ;
  246. ;            
  247. ;  CALL CHDIR(PATH,ICODE)    
  248. ;
  249. ;       PATH  = CHARACTER*64          (INPUT PATH NAME)
  250. ;       ICODE = INTEGER               (RETURN CODE)
  251. ;
  252. ;    NOTE: PATH MUST CONTAIN THE PATH NAME, TERMINATED BY
  253. ;          A ZERO BYTE.  THE DRIVE LETTER AND COLON AND
  254. ;          BACKSLASH MAY BE AT THE START OF THE STRING.   
  255. ;
  256. CHDIR   PROC    FAR             ;SET PATH NAME
  257. ;
  258.     SETFRAME
  259. ;
  260.     GETPARM    1,2    
  261.     MOV    STRING,BX    ;SAVE PTR TO INPUT STRING AREA
  262.     MOV    STRING_SEG,ES    ;AND SEG
  263. ;
  264.     PUSH    DS        ;SAVE DS
  265.     PUSH    ES
  266.     POP    DS
  267.     MOV    DX,BX        ;SET UP PATH STRING POINTER
  268. ;
  269.     MOV    AH,3BH        ;SET DIRECTORY PATH
  270.         DOS
  271. ;
  272.     GETPARM    2,2        ;POINT TO ICODE
  273.     MOV    AH,0        ;CLEAR OUT AH
  274.     MOV    ES:[BX],AX    ;STORE IT
  275. ;    
  276.     POP    DS        ;RESTORE DS
  277.         POPRET    2
  278. CHDIR    ENDP
  279.  
  280. ;----------------------------------
  281. ;  GETDFS: GET DISK FREE SPACE IN BYTES.
  282. ;
  283. ;            
  284. ;  CALL GETDFS(IDRIVE,IBYTES,ISECT,ICLUST)
  285. ;    
  286. ;    IDRIVE= INTEGER*2          (DRIVE NUMBER)
  287. ;       IBYTES= INTEGER*2             (NUMBER OF BYTES /SECTOR)
  288. ;    ISECT = INTEGER*2          (NUMBER OF SECTORS / CLUSTER)
  289. ;    ICLUST= INTEGER*2          (NUMBER OF CLUSTERS REMAINING)
  290. ;       
  291. ;    IF ISECT = FFFFh THEN ERROR: INVALID DRIVE CODE
  292. ;
  293. GETDFS  PROC    FAR             ;GET SPACE REMAINING
  294. ;
  295.     SETFRAME
  296. ;    
  297.     GETPARM    1,4    
  298.     MOV    DX,ES:[BX]      ;GET DRIVE NUMBER
  299. ;
  300.     MOV    AH,36H        ;SET DIRECTORY PATH
  301.         DOS
  302. ;
  303. ; THIS FUNCTION RETURNS:  AX=FFFF IF ERROR,
  304. ;    BX = NUMBER OF CLUSTERS    AVAILABLE
  305. ;    CX = NUMBER OF BYTES PER SECTOR
  306. ;    AX = NUMBER OF SECTORS PER CLUSTER
  307. ;
  308. ;  THEREFORE, IBYTES = AX * BX * CX
  309. ;
  310.     PUSH    BX        ;PUSH ICLUST
  311.     GETPARM 2,4
  312.     MOV    ES:[BX],CX    ;SAVE IBYTES
  313. ;
  314.     GETPARM 3,4        ;SAVE ISECT
  315.     MOV    ES:[BX],AX
  316. ;
  317.     GETPARM    4,4
  318.     POP    AX
  319.     MOV    ES:[BX],AX    ;SAVE ICLUST
  320. ;    
  321.         POPRET    4
  322. GETDFS    ENDP
  323. ;
  324. CODE    ENDS
  325.     END 
  326.